1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
|
(*
* Vericert: Verified high-level synthesis.
* Copyright (C) 2020-2022 Yann Herklotz <yann@yannherklotz.com>
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <https://www.gnu.org/licenses/>.
*)
Require Import compcert.backend.Registers.
Require Import compcert.common.AST.
Require Import compcert.common.Events.
Require Import compcert.common.Globalenvs.
Require Import compcert.common.Memory.
Require Import compcert.common.Smallstep.
Require Import compcert.common.Values.
Require Import compcert.lib.Coqlib.
Require Import compcert.lib.Integers.
Require Import compcert.lib.Maps.
Require Import compcert.verilog.Op.
Require Import vericert.hls.RTLBlockInstr.
(*|
========
RTLBlock
========
|*)
Definition bb := instr.
Definition bblock := @bblock bb.
Definition code := @code bb.
Definition function := @function bb.
Definition fundef := @fundef bb.
Definition program := @program bb.
Definition funsig := @funsig bb.
Definition stackframe := @stackframe bb.
Definition state := @state bb.
Definition genv := @genv bb.
(*|
Semantics
=========
We first describe the semantics by assuming a global program environment with
type ~genv~ which was declared earlier.
|*)
Section RELSEM.
Context (ge: genv).
(*|
Instruction list step
---------------------
The ``step_instr_list`` definition describes the execution of a list of
instructions in one big step, inductively traversing the list of instructions
and applying the ``step_instr``.
This is simply using the high-level function ``step_list``, which is a general
function that can execute lists of things, given their execution rule.
|*)
Definition step_instr_list := step_list (step_instr ge).
(*|
Top-level step
--------------
The step function itself then uses this big step of the list of instructions to
then show a transition from basic block to basic block. The one particular
aspect of this is that the basic block is also part of the state, which has to
be correctly set during the execution of the function. Function calls and
function returns then also need to set the basic block properly. This means
that the basic block of the returning function also needs to be stored in the
stackframe, as that is the only assumption one can make when returning from a
function.
|*)
Variant step: state -> trace -> state -> Prop :=
| exec_bblock:
forall s f sp pc rs rs' m m' bb pr pr',
step_instr_list sp (mk_instr_state rs pr m) bb
(mk_instr_state rs' pr' m') ->
step (State s f sp pc bb rs pr m) E0 (JumpState s f sp pc rs' pr' m')
| exec_jumpstate :
forall s f sp pc rs pr m block t st,
f.(fn_code) ! pc = Some block ->
step_cf_instr ge (JumpState s f sp pc rs pr m) block.(bb_exit) t st ->
step (JumpState s f sp pc rs pr m) t st
| exec_function_internal:
forall s f args m m' stk bb cf,
Mem.alloc m 0 f.(fn_stacksize) = (m', stk) ->
f.(fn_code) ! (f.(fn_entrypoint)) = Some (mk_bblock bb cf) ->
step (Callstate s (Internal f) args m)
E0 (State s f
(Vptr stk Ptrofs.zero)
f.(fn_entrypoint)
bb
(init_regs args f.(fn_params))
(PMap.init false)
m')
| exec_function_external:
forall s ef args res t m m',
external_call ef ge args m t res m' ->
step (Callstate s (External ef) args m)
t (Returnstate s res m')
| exec_return:
forall res f sp pc rs s vres m pr,
step (Returnstate (Stackframe res f sp pc rs pr :: s) vres m)
E0 (JumpState s f sp pc (rs#res <- vres) pr m).
End RELSEM.
Inductive initial_state (p: program): state -> Prop :=
| initial_state_intro: forall b f m0,
let ge := Genv.globalenv p in
Genv.init_mem p = Some m0 ->
Genv.find_symbol ge p.(prog_main) = Some b ->
Genv.find_funct_ptr ge b = Some f ->
funsig f = signature_main ->
initial_state p (Callstate nil f nil m0).
Inductive final_state: state -> int -> Prop :=
| final_state_intro: forall r m,
final_state (Returnstate nil (Vint r) m) r.
Definition semantics (p: program) :=
Semantics step (initial_state p) final_state (Genv.globalenv p).
|
