1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
|
(* *********************************************************************)
(* *)
(* The Compcert verified compiler *)
(* *)
(* Xavier Leroy, INRIA Paris-Rocquencourt *)
(* *)
(* Copyright Institut National de Recherche en Informatique et en *)
(* Automatique. All rights reserved. This file is distributed *)
(* under the terms of the INRIA Non-Commercial License Agreement. *)
(* *)
(* *********************************************************************)
(** Function calling conventions and other conventions regarding the use of
machine registers and stack slots. *)
Require Import Coqlib.
Require Import Decidableplus.
Require Import AST.
Require Import Events.
Require Import Locations.
(** * Classification of machine registers *)
(** Machine registers (type [mreg] in module [Locations]) are divided in
the following groups:
- Callee-save registers, whose value is preserved across a function call.
- Caller-save registers that can be modified during a function call.
We follow the x86-32 application binary interface (ABI) in our choice
of callee- and caller-save registers.
*)
Definition is_callee_save (r: mreg) : bool :=
match r with
| AX | CX | DX => false
| BX | SI | DI | BP => true
| X0 | X1 | X2 | X3 | X4 | X5 | X6 | X7 => false
| FP0 => false
end.
Definition int_caller_save_regs := AX :: CX :: DX :: nil.
Definition float_caller_save_regs := X0 :: X1 :: X2 :: X3 :: X4 :: X5 :: X6 :: X7 :: nil.
Definition int_callee_save_regs := BX :: SI :: DI :: BP :: nil.
Definition float_callee_save_regs : list mreg := nil.
Definition destroyed_at_call :=
List.filter (fun r => negb (is_callee_save r)) all_mregs.
Definition dummy_int_reg := AX. (**r Used in [Regalloc]. *)
Definition dummy_float_reg := X0. (**r Used in [Regalloc]. *)
(** * Function calling conventions *)
(** The functions in this section determine the locations (machine registers
and stack slots) used to communicate arguments and results between the
caller and the callee during function calls. These locations are functions
of the signature of the function and of the call instruction.
Agreement between the caller and the callee on the locations to use
is guaranteed by our dynamic semantics for Cminor and RTL, which demand
that the signature of the call instruction is identical to that of the
called function.
Calling conventions are largely arbitrary: they must respect the properties
proved in this section (such as no overlapping between the locations
of function arguments), but this leaves much liberty in choosing actual
locations. To ensure binary interoperability of code generated by our
compiler with libraries compiled by another compiler, we
implement the standard x86 conventions. *)
(** ** Location of function result *)
(** The result value of a function is passed back to the caller in
registers [AX] or [FP0], depending on the type of the returned value.
We treat a function without result as a function with one integer result. *)
Definition loc_result (s: signature) : list mreg :=
match s.(sig_res) with
| None => AX :: nil
| Some (Tint | Tany32) => AX :: nil
| Some (Tfloat | Tsingle) => FP0 :: nil
| Some Tany64 => X0 :: nil
| Some Tlong => DX :: AX :: nil
end.
(** The result registers have types compatible with that given in the signature. *)
Lemma loc_result_type:
forall sig,
subtype_list (proj_sig_res' sig) (map mreg_type (loc_result sig)) = true.
Proof.
intros. unfold proj_sig_res', loc_result. destruct (sig_res sig) as [[]|]; auto.
Qed.
(** The result locations are caller-save registers *)
Lemma loc_result_caller_save:
forall (s: signature) (r: mreg),
In r (loc_result s) -> is_callee_save r = false.
Proof.
intros.
assert (r = AX \/ r = DX \/ r = FP0 \/ r = X0).
unfold loc_result in H. destruct (sig_res s) as [[]|]; simpl in H; intuition.
destruct H0 as [A | [A | [A | A]]]; subst r; reflexivity.
Qed.
(** ** Location of function arguments *)
(** All arguments are passed on stack. (Snif.) *)
Fixpoint loc_arguments_rec
(tyl: list typ) (ofs: Z) {struct tyl} : list loc :=
match tyl with
| nil => nil
| Tint :: tys => S Outgoing ofs Tint :: loc_arguments_rec tys (ofs + 1)
| Tfloat :: tys => S Outgoing ofs Tfloat :: loc_arguments_rec tys (ofs + 2)
| Tsingle :: tys => S Outgoing ofs Tsingle :: loc_arguments_rec tys (ofs + 1)
| Tlong :: tys => S Outgoing (ofs + 1) Tint :: S Outgoing ofs Tint :: loc_arguments_rec tys (ofs + 2)
| Tany32 :: tys => S Outgoing ofs Tany32 :: loc_arguments_rec tys (ofs + 1)
| Tany64 :: tys => S Outgoing ofs Tany64 :: loc_arguments_rec tys (ofs + 2)
end.
(** [loc_arguments s] returns the list of locations where to store arguments
when calling a function with signature [s]. *)
Definition loc_arguments (s: signature) : list loc :=
loc_arguments_rec s.(sig_args) 0.
(** [size_arguments s] returns the number of [Outgoing] slots used
to call a function with signature [s]. *)
Fixpoint size_arguments_rec
(tyl: list typ) (ofs: Z) {struct tyl} : Z :=
match tyl with
| nil => ofs
| ty :: tys => size_arguments_rec tys (ofs + typesize ty)
end.
Definition size_arguments (s: signature) : Z :=
size_arguments_rec s.(sig_args) 0.
(** Argument locations are either caller-save registers or [Outgoing]
stack slots at nonnegative offsets. *)
Definition loc_argument_acceptable (l: loc) : Prop :=
match l with
| R r => is_callee_save r = false
| S Outgoing ofs ty => ofs >= 0 /\ (typealign ty | ofs)
| _ => False
end.
Remark loc_arguments_rec_charact:
forall tyl ofs l,
In l (loc_arguments_rec tyl ofs) ->
match l with
| S Outgoing ofs' ty => ofs' >= ofs /\ typealign ty = 1
| _ => False
end.
Proof.
induction tyl; simpl loc_arguments_rec; intros.
- destruct H.
- assert (REC: forall ofs1, In l (loc_arguments_rec tyl ofs1) -> ofs1 > ofs ->
match l with
| R _ => False
| S Local _ _ => False
| S Incoming _ _ => False
| S Outgoing ofs' ty => ofs' >= ofs /\ typealign ty = 1
end).
{ intros. exploit IHtyl; eauto. destruct l; auto. destruct sl; intuition omega
. }
destruct a; simpl in H; repeat (destruct H);
((eapply REC; eauto; omega) || (split; [omega|reflexivity])).
Qed.
Lemma loc_arguments_acceptable:
forall (s: signature) (l: loc),
In l (loc_arguments s) -> loc_argument_acceptable l.
Proof.
unfold loc_arguments; intros.
exploit loc_arguments_rec_charact; eauto.
unfold loc_argument_acceptable.
destruct l as [r | [] ofs ty]; intuition auto. rewrite H2; apply Z.divide_1_l.
Qed.
Hint Resolve loc_arguments_acceptable: locs.
(** The offsets of [Outgoing] arguments are below [size_arguments s]. *)
Remark size_arguments_rec_above:
forall tyl ofs0, ofs0 <= size_arguments_rec tyl ofs0.
Proof.
induction tyl; simpl; intros.
omega.
apply Zle_trans with (ofs0 + typesize a); auto.
generalize (typesize_pos a); omega.
Qed.
Lemma size_arguments_above:
forall s, size_arguments s >= 0.
Proof.
intros; unfold size_arguments. apply Zle_ge.
apply size_arguments_rec_above.
Qed.
Lemma loc_arguments_bounded:
forall (s: signature) (ofs: Z) (ty: typ),
In (S Outgoing ofs ty) (loc_arguments s) ->
ofs + typesize ty <= size_arguments s.
Proof.
intros until ty. unfold loc_arguments, size_arguments. generalize (sig_args s) 0.
induction l; simpl; intros.
- contradiction.
- Ltac decomp :=
match goal with
| [ H: _ \/ _ |- _ ] => destruct H; decomp
| [ H: S _ _ _ = S _ _ _ |- _ ] => inv H
| _ => idtac
end.
destruct a; simpl in H; decomp; auto; try apply size_arguments_rec_above.
simpl typesize. replace (z + 1 + 1) with (z + 2) by omega. apply size_arguments_rec_above.
simpl typesize. apply Zle_trans with (ofs + 2). omega. apply size_arguments_rec_above.
Qed.
Lemma loc_arguments_main:
loc_arguments signature_main = nil.
Proof.
reflexivity.
Qed.
|
